[return cond="const._saveload.inited"]
	[let name="const._saveload.inited" text=true]

	[sys_syslay.init]
	[loadplugin fn="Mnu_InfoThumb"]

	[event global=true call=true key=s label=*quick_save]
	[event global=true call=true key=l label=*quick_load]

	[let name="sys:_saveload.quick_place" text="&4 *12" cond="sys:_saveload.quick_place == null"]

[macro name="_sl.put_page_button"]
	[button enabled=false cond="sys:_saveload.page == mp:page" layer="_syslay.mes" pic="&'MnuUp_Page'+ (mp:page+1)" left="&mp:page *100 +195" top=16]
	[button cond="sys:_saveload.page != mp:page" layer="_syslay.mes" pic="&'MnuUp_btnPage'+ (mp:page+1)" left="&mp:page *100 +195" top=16 global=true label=*page enterse=&sysse_choice clickse=&sysse_ok1 arg=%page]
[endmacro]

[macro name="_sl.put_common"]
	[let name="x" text="&mp:x *235 +57"]
	[let name="y" text="&mp:y *200 +66"]
	[let name="place" text="&mark_p +mp:x +mp:y *4"]
	[let name="exsits" text="&sys:const.an.bookmark[place] != null"]
	[let name="&'pos.'+ place +'.x'" text=&x]
	[let name="&'pos.'+ place +'.y'" text=&y]

	[button enabled=false layer="_syslay.mes" pic="& 'app-storage:/bookmark/'+ place +'.jpg'" left=&x top=&y cond="exsits && const.flash.system.Capabilities.playerType == 'Desktop'"]
[endmacro]
[macro name="_sl.set_pos"]
	&pos.x =mp:place%4 *235 +57
	&pos.y =mp:place¥4 *200 +66
[endmacro]

[macro name="_sl.put_save_button"]
	[_sl.put_common]

	[button layer="_syslay.mes" pic="Mnu_btnThumb" left=&x top=&y global=true label=*save enterse=&sysse_choice arg=&place hint="&'保存日時：'+ sys:const.an.bookmark[place].UpdateTime" cond=exsits]

	[button layer="_syslay.mes" pic="_saveloadBtn_nouse" left="&x -5" top="&y -6" global=true label=*save enterse=&sysse_choice arg=&place cond="! exsits"]
[endmacro]

[macro name="_sl.put_load_button"]
	[_sl.put_common]

	[button layer="_syslay.mes" pic="Mnu_btnThumb" left=&x top=&y global=true label=*load enterse=&sysse_choice cond=exsits arg=&place hint="&'保存日時：'+ sys:const.an.bookmark[place].UpdateTime"]

	[button enabled=false layer="_syslay.mes" pic="Tips_QL" left=&x top="&y +150" cond="exsits && (sys:_saveload.page == 4) && (place == (sys:_saveload.quick_place +11) % 12 +(4 *12))"]
	[button enabled=false layer="_syslay.mes" pic="Tips_QS" left=&x top="&y +150" cond="(sys:_saveload.page == 4) && (place == sys:_saveload.quick_place)"]
[endmacro]

;*********************************************************
[add_face name="_saveloadTitleLoad" dx=25 dy=14]
[add_face name="_saveloadTitleSave" dx=25 dy=14]

[return]

;*********************************************************
;	TitleMenu -> Load
*title_load
	[let name="しおりモード" text="Load"]
	[let name="Mnu_Title" text="_saveloadTitleLoad"]
	[let name="呼び元" text="Title"]
[jump label=*main]

;*********************************************************
;	右クリック -> Load
*rclick_load
	[return cond="! isGameState"]

	[let name="しおりモード" text="Load"]
	[let name="Mnu_Title" text="_saveloadTitleLoad"]
	[let name="呼び元" text="Text"]
[jump label=*main]

;*********************************************************
;	右クリック -> Save
*rclick_save
	[return cond="! isGameState"]

	[let name="しおりモード" text="Save"]
	[let name="Mnu_Title" text="_saveloadTitleSave"]
	[let name="呼び元" text="Text"]
[jump label=*main]

;*********************************************************
*main
	[enable_event enabled=false]
	[clear_event]

	[let name="sys:_saveload.page" text=0 cond="sys:_saveload.page == null"]
	[let name="sys:_saveload.page" text=3 cond="sys:_saveload.page == 4 && しおりモード == 'Save'"]
	[lay layer="_syslay.bg" fn="_saveload" face=&Mnu_Title visible=false]
		[zoom_tsy layer="_syslay.bg" time=400 visible=true]
	[lay layer="_syslay.mes" page=back visible=true float=true]
	[let name="同画面遷移か" text=false]

*chg_page
	[enable_event layer="_syslay.mes" enabled=false]
	[clear_lay layer="_syslay.mes" page=back]

	[_sl.put_page_button page=0]
	[_sl.put_page_button page=1]
	[_sl.put_page_button page=2]
	[_sl.put_page_button page=3]
	[_sl.put_page_button page=4 cond="しおりモード == 'Load'"]

	[let name="mark_p" text="&sys:_saveload.page * 12"]
	[call label=*btn_save cond="しおりモード == 'Save'"]
	[call label=*btn_load cond="しおりモード == 'Load'"]

	[button layer="_syslay.mes" pic="Mnu_btnReturn" left=916 top=16 global=true label=*exit hint="戻る" enterse=&sysse_choice clickse=&sysse_cancel join=true]

		[wait_tsy layer="_syslay.bg" backlay=true canskip=false]

	[trans layer="_syslay.mes" time=200 cond="同画面遷移か"]
	[trans layer="_syslay.mes" time=0 cond="! 同画面遷移か"]
	[wt]
	[let name="同画面遷移か" text=true]

	[let name="isGameState" text=false]
*retry
	[event key=rightclick label=*cancel]
	[event key=command label=*cancel]
	[event key=control label=*cancel]
	[event key=end label=*cancel]
	[event key=shift label=*cancel]
;	[gesture_event swipe=*swipe f2tap=*cancel f3tap=*cancel]
	[event key=page_up label=*left]
	[event key=page_down label=*right]
	[event key=downwheel label=*left]
	[event key=upwheel label=*right]
	[enable_event layer="_syslay.mes" enabled=true]
	[set_focus to=null]
[s]

;*********************************************************
*swipe
	[jump label=*left cond="const.an.eventArg == 'l'"]
	[jump label=*right cond="const.an.eventArg == 'r'"]
	[jump label=*last cond="const.an.eventArg == 'u'"]
	[jump label=*top cond="const.an.eventArg == 'd'"]
[jump label=*chg_page]

*last
	[let name=page_max text=3]	; 最大ページ番号
	[let name=page_max text=&page_max+1 cond="しおりモード == 'Load'"]
	[jump label=*retry cond="sys:_saveload.page == page_max"]
	[let name="sys:_saveload.page" text=page_max]
[jump label=*chg_page]

*left
	[let name=page_max text=3]	; 最大ページ番号
	[let name=page_max text=&page_max+1 cond="しおりモード == 'Load'"]
	[jump label=*retry cond="sys:_saveload.page == page_max"]
	[let name="sys:_saveload.page" text="&sys:_saveload.page +1" cast=int]
[jump label=*chg_page]

*top
	[jump label=*retry cond="sys:_saveload.page == 0"]
	[let name="sys:_saveload.page" text=0]
[jump label=*chg_page]

*right
	[jump label=*retry cond="sys:_saveload.page == 0"]
	[let name="sys:_saveload.page" text="&sys:_saveload.page -1" cast=int]
[jump label=*chg_page]

;*********************************************************
*page
	[let name="sys:_saveload.page" text=&const.an.eventArg]
	[jump label=*chg_page]

;*********************************************************
*btn_save
	[_sl.put_save_button * x=0 y=0]
	[_sl.put_save_button * x=1 y=0]
	[_sl.put_save_button * x=2 y=0]
	[_sl.put_save_button * x=3 y=0]

	[_sl.put_save_button * x=0 y=1]
	[_sl.put_save_button * x=1 y=1]
	[_sl.put_save_button * x=2 y=1]
	[_sl.put_save_button * x=3 y=1]

	[_sl.put_save_button * x=0 y=2]
	[_sl.put_save_button * x=1 y=2]
	[_sl.put_save_button * x=2 y=2]
	[_sl.put_save_button * x=3 y=2]
[return]

;*********************************************************
*btn_load
	[_sl.put_load_button * x=0 y=0]
	[_sl.put_load_button * x=1 y=0]
	[_sl.put_load_button * x=2 y=0]
	[_sl.put_load_button * x=3 y=0]

	[_sl.put_load_button * x=0 y=1]
	[_sl.put_load_button * x=1 y=1]
	[_sl.put_load_button * x=2 y=1]
	[_sl.put_load_button * x=3 y=1]

	[_sl.put_load_button * x=0 y=2]
	[_sl.put_load_button * x=1 y=2]
	[_sl.put_load_button * x=2 y=2]
	[_sl.put_load_button * x=3 y=2]
[return]

;*********************************************************
*save
	[let name="place" text="&const.an.eventArg"]
	[let name="exsits" text="&sys:const.an.bookmark[place] != null"]
	[se fn=&sysse_ok1 buf=SYS]
	[jump label=*ask_end_save cond="! exsits"]

	[enable_event layer="_syslay.mes" enabled=false]
		[_sl.set_pos place=&place]
		[plugin name="Mnu_InfoThumb" visible=true left=&pos.x top=&pos.y float=true]

		[ask_ync mes="しおりを上書き保存しますか？"]
			;#FONT	しおりを上書き保存しますか？

		[plugin name="Mnu_InfoThumb" visible=false]
	[enable_event layer="_syslay.mes" enabled=true]
	[jump label=*retry cond="_yesno != 'y'"]

*ask_end_save
	[call label=*do_save]
[jump label=*exit]

*do_save
	[snapshot fn="& 'app-storage:/bookmark/'+ place" layer="base,0,1,2,mes" width=220 height=165 quality=90 smoothing=true]
*do_save_noss
	[let name="enabled" text="&save:const.an.layer.mes.enabled|true"]
	[enable_event enabled=true]	; この状態も保存されるので一時変更
	[save place=&place path="app-storage:/bookmark/"]
	[enable_event enabled="&enabled"]
[return]

*do_save_resume
	; 変数placeを変更しないよう注意。呼び元で使用している。
	[let name="enabled" text="&save:const.an.layer.mes.enabled|true"]
	[enable_event enabled=true]	; この状態も保存されるので一時変更
	[save place=99999]
	[enable_event enabled="&enabled"]
[return]

;*****************************
*quick_save
	[return cond="! isGameState"]

	[let name="place" text="&sys:_saveload.quick_place"]
	[call label=*do_save]
	[let name="sys:_saveload.quick_place" text="&(place +1) % 12 +(4 *12)"]

	[notice text="クイックセーブしました" left="&const.flash.display.Stage.stageWidth -10 -300" top=10]
[return]

;*********************************************************
*load
	[let name="place" text="&const.an.eventArg"]
	[jump label=*ask_end_load cond="呼び元 == 'Title'"]
	[se fn=&sysse_ok1 buf=SYS]

	[enable_event layer="_syslay.mes" enabled=false]
		[_sl.set_pos place=&place]
		[plugin name="Mnu_InfoThumb" visible=true left=&pos.x top=&pos.y float=true]

		[ask_ync mes="しおりを読み込みますか？"]
			;#FONT	しおりを読み込みますか？

		[plugin name="Mnu_InfoThumb" visible=false]
	[enable_event layer="_syslay.mes" enabled=true]
	[jump label=*retry cond="_yesno != 'y'"]
	[jump label=*end_load]

*ask_end_load
	[se fn=&sysse_ok2_long buf=SYS]
*end_load
	; *** ブラックアウト ***
	[clear_lay layer="_syslay.mes" page=back]
	[lay layer="_syslay.bg" page=back visible=false]
	[trans layer="_syslay.mes,_syslay.bg" time=200]

*do_load
	[sys_scenario_start no_resume_save=true]
	[copybookmark from=&place to=99999]
	[load place=&place]
;	[load place=&place fn=_saveload label=*do_load_init]

*do_load_resume
	[se fn=&sysse_ok2_long buf=SYS]
	[notice text="前回終了ポイントから再開します" left="&const.flash.display.Stage.stageWidth -10 -300" top=10]
	[sys_scenario_start no_resume_save=true]
	[load place=99999]
;	[load place=99999 fn=_saveload label=*do_load_init]

; ロード後最初にしたい共通処理
*do_load_init
	
[return]

;*****************************
*quick_load
	[return cond="! isGameState"]
	[return cond="sys:_saveload.quick_place == null"]
	[let name="place" text="&(sys:_saveload.quick_place +11) % 12 +(4 *12)"]
	[return cond="sys:const.an.bookmark[place] == null"]

	[enable_event enabled=false]
		[ask_ync_cleartext]
		[button enabled=false layer="mes_yesno" page=fore pic="& 'app-storage:/bookmark/'+ place +'.jpg'" left=570 top=220]
		[ask_ync mes="クイックロードしますか？" no_cleartext=true]
			;#FONT	クイックロードしますか？
	[enable_event enabled=true]
	[return cond="_yesno != 'y'"]
[jump label=*do_load]

;*********************************************************
*cancel
	[se fn=&sysse_cancel buf=SYS]
*exit
	[lay layer="_syslay.mes" page=fore visible=false]
	[lay layer="_syslay.mes" page=back visible=false]
	[clear_lay layer="_syslay.mes" page=both]
	[zoom_tsy layer="_syslay.bg" visible=false time=400]

	[enable_event enabled=true]
	[set_focus to=null]
	[let name="isGameState" text=true cond="呼び元=='Text'"]
[return]